Quick and crude cuesheet generator for GD-ROMs

Post discussions on how to downsample and hack CD-based games here. Discuss the best ways to fit your backed-up game onto a CD-R, or other ways to play GDI files on a real console.

Moderator: Moderators

Post Reply
User avatar
darcagn
Site Founder & Admin
Site Founder & Admin
Posts: 317
Joined: Fri Apr 06, 2007 11:12 am

Quick and crude cuesheet generator for GD-ROMs

Post by darcagn » Tue Jul 09, 2013 10:35 pm

Double click batch file, it will ask you how many tracks the total GD-ROM dump has
acceptable input is 3, 5-99

Batch file will then generate a hdsession.cue cuesheet file that you can use to access the gd-rom's high density information. See this thread for a little more information on this.

This is a quick and crude file, it makes lots of assumptions:
  • your data tracks are raw/2352
  • your track files must be in the filename format trackXX.(bin/raw)
  • the high density session begins with track03.bin
  • track03 and the last track of the hd session are data, the rest are cdda
  • track03 begins at LBA 45000
  • there will be a 150-sector gap between two tracks of different data types
This should all be OK for you if you dumped with httpd-ack on default settings and your gd-rom is an official gd-rom without mastering defects. if this doesn't work for your particular dump, post here and let me know and i'll help you figure it out/modify my script as necessary.

Download here: http://dumpcast.dcemulation.org/dccuegen.bat

or paste to a blank file from this text:

Code: Select all

@echo off
echo.
echo dccuegen.bat - quick and crude cuesheet
echo     generator for dreamcast dumps
echo.
echo      written by darcagn
echo      http://dumpcast.dcemulation.org/
echo.
set /p trackcount="Enter the number of total tracks: " %=%
if %trackcount% lss 3 goto funnytracks
if %trackcount% gtr 99 goto funnytracks
if %trackcount% equ 3 goto threetracks
if %trackcount% equ 4 goto funnytracks
if %trackcount% gtr 3 goto moartracks
:funnytracks
echo %trackcount% tracks? i don't believe you
goto exit
:threetracks
echo generating cuesheet for a high density
echo session consisting of a single track (no cdda)
echo FILE "track03.bin" BINARY > hdsession.cue
echo TRACK 03 MODE1/2352 >> hdsession.cue
echo PREGAP 10:00:00 >> hdsession.cue
echo INDEX 01 00:00:00 >> hdsession.cue
goto done
:moartracks
echo  generating cuesheet for a gd-rom
echo  consisting of %trackcount% tracks total
echo FILE "track03.bin" BINARY > hdsession.cue
echo TRACK 03 MODE1/2352 >> hdsession.cue
echo PREGAP 10:00:00 >> hdsession.cue
echo INDEX 01 00:00:00 >> hdsession.cue
echo POSTGAP 00:02:00 >> hdsession.cue
set loop=4
:loop
echo. >> hdsession.cue
if %loop% gtr 9 (echo FILE "track%loop%.raw" BINARY >> hdsession.cue) else (echo FILE "track0%loop%.raw" BINARY >> hdsession.cue)
if %loop% gtr 9 (echo TRACK %loop% AUDIO >> hdsession.cue) else (echo TRACK 0%loop% AUDIO >> hdsession.cue)
echo INDEX 01 00:00:00 >> hdsession.cue
set /a loop=%loop%+1
if %loop% equ %trackcount% (goto escapeloop) else (goto loop)
:escapeloop
echo POSTGAP 00:02:00 >> hdsession.cue
echo. >> hdsession.cue
if %loop% gtr 9 (echo FILE "track%loop%.bin" BINARY >> hdsession.cue) else (echo FILE "track0%loop%.bin" BINARY >> hdsession.cue)
if %loop% gtr 9 (echo TRACK %loop% MODE1/2352 >> hdsession.cue) else (echo TRACK 0%loop% MODE1/2352 >> hdsession.cue)
echo INDEX 01 00:00:00 >> hdsession.cue
:done
echo all done!
:exit
Post Reply